// kass.txt
// A modification on basicnpc. Modifications stolen from various Vogel scripts.
// When SDF set, moves to waypoint, then stops moving.
// Memory Cells:
//   Cell 0 - How creature moves.
//     0 - If 0, wander randomly. 
//     1 - Stands still until a target appears.
//     2 - Completely immobile, even if target appears.
//   Cell 1,2 - Stuff done flag. If both 0, nothing. Otherwise when this 
//     is killed, set to 1. (Example: If cell 1 is 3 and cell 2 is 5, when
//     creature is killed, sets SDF(3,5) to 1.)
//   Cell 3 - Dialogue node to start with if talked to. if left at 0, this
//     character doesn't talk.
//	Cell 4 - waypoint to go to
//	Cell 5,6 - SDF for char to move to waypoint. If both 0, none.
//	Note: This SDF must be set to 1 for char to move.
//	Cell 7 - Dialogue node to start with when char has arrived.
//	Cell 8,9 - SDF for char to not talk to party

begincreaturescript;

variables;

short i,target,party_sighted;

body;

beginstate INIT_STATE;
	if (get_memory_cell(0) == 2)
		set_mobility(ME,0);
	break;

beginstate DEAD_STATE;
	// Set the appropriate stuff done flag for this character being dead
	if ((get_memory_cell(1) != 0) || (get_memory_cell(2) != 0))
		set_flag(get_memory_cell(1),get_memory_cell(2),1);
break;

beginstate START_STATE; 
	// If Memory Cells 5 or 6 aren't zero and the flag is set,
	// go to waypoint. Note: char can't talk while moving.
	if (((get_memory_cell(5) != 0) || (get_memory_cell(6) != 0)) && (get_flag(get_memory_cell(5),get_memory_cell(6)) == 1))
		{set_memory_cell(3,0);
		set_state(4); }

	// if I have a target for some reason, go attack it
	if (target_ok()) {
		if (dist_to_char(get_target()) <= 16)
			set_state(3);
			else set_target(ME,-1);
		}
	
	// Look for a target, attack it if visible
	if (select_target(ME,8,0)) {
		do_attack();
		set_state(3);
		}
		
	// Have I been hit? Strike back!
	if (who_hit_me() >= 0) {
		set_target(ME,who_hit_me());
		do_attack();
		set_state(3);
		}
		
	// Otherwise, just peacefully move around. Go back to start, if I'm too far
	// from where I started.
	if ((my_dist_from_start() >= 6) || ((my_dist_from_start() > 0) && (get_memory_cell(0) > 0))) {
		if (get_ran(1,1,100) < 40) 
			return_to_start(ME,1);
		}
		else if (get_memory_cell(0) == 0) {
			fidget(ME,25);
			}

	// Once I see the party, I approach it and talk to them, unless SDF is set.
	// Memory cells 8 and 9 define which SDF to set.
	if (can_see_char(1000))
		party_sighted = 1;
	if ((get_flag(get_memory_cell(8),get_memory_cell(9)) == 0) && (dist_to_party() <= 6) && (party_sighted > 0)) {
		if (dist_to_party() <= 1) {
			set_flag(get_memory_cell(8),get_memory_cell(9),1);
			begin_talk_mode(get_memory_cell(3));
			}
			else approach_char(ME,random_group_member(0),2);
		}
		else if (my_dist_from_start() >= 1) {
			return_to_start(ME,0);
			}

	// if we're in combat and the above didn't give me anything to do, just
	// stop now. Otherwise, game will keep running script, and that eats up CPU time.
	if (am_i_doing_action() == FALSE)
		end_combat_turn();
break;

beginstate 3; // attacking
	if (target_ok() == FALSE)
		set_state(START_STATE);
	do_attack();
break;

beginstate 4; // moving to waypoint and then holding still
	if (approach_waypoint(ME,get_memory_cell(4),0) > 0)
		{set_mobility(ME,0);
		set_memory_cell(3,get_memory_cell(7));
		set_flag(get_memory_cell(5),get_memory_cell(6),2);
		set_state(START_STATE); }	
break;

beginstate TALKING_STATE;
	if (get_memory_cell(3) == 0) {
		print_str("Talking: It doesn't respond.");
		end();
		}
	begin_talk_mode(get_memory_cell(3));
break;
