// twopts.txt
// Exactly like the basic creature script, but spends all its time walking 
// and forth between two waypoints.
// Memory Cells:
//   Cell 0 - Unused
//   Cell 1,2 - Stuff done flag. If both 0, nothing. Otherwise when this 
//     is killed, set to 1. (Example: If cell 1 is 3 and cell 2 is 5, when
//     creature is killed, sets SDF(3,5) to 1.)
//   Cell 3 - Dialogue node to start with if talked to. if left at 0, this
//     character doesn't talk.
//   Cell 4,5 - Two waypoints. The character walks from one to the other.

begincreaturescript;

variables;

short i,target;
short path_a_or_b = 0;

body;

beginstate INIT_STATE;
	break;

beginstate DEAD_STATE;
	// Set the appropriate stuff done flag for this character being dead
	if ((get_memory_cell(1) != 0) || (get_memory_cell(2) != 0))
		set_flag(get_memory_cell(1),get_memory_cell(2),1);
break;

beginstate START_STATE; 
	// if I have a target for some reason, go attack it
	if (target_ok()) {
		if (dist_to_char(get_target()) <= 16)
			set_state(3);
			else set_target(ME,-1);
		}
	
	// Look for a target, attack it if visible
	if (select_target(ME,8,0)) {
		do_attack();
		set_state(3);
		}
		
	// Have I been hit? Strike back!
	if (who_hit_me() >= 0) {
		set_target(ME,who_hit_me());
		do_attack();
		set_state(3);
		}
	
	// Otherwise, walk between the two waypoints.	
	if (path_a_or_b == 0) {
		if (get_ran(1,0,100) < 20) {
			if (approach_waypoint(ME,get_memory_cell(4),1))
				path_a_or_b = 1;	
			}	
		}
		else {
			if (get_ran(1,0,100) < 20) {
				if (approach_waypoint(ME,get_memory_cell(5),1))
					path_a_or_b = 0;		
				}
			}

	// if we're in combat and the above didn't give me anything to do, just
	// stop now. Otherwise, game will keep running script, and that eats up CPU time.
	if (am_i_doing_action() == FALSE)
		end_combat_turn();
break;

beginstate 3; // attacking
	if (target_ok() == FALSE)
		set_state(START_STATE);
	do_attack();
break;

beginstate TALKING_STATE;
	if (get_memory_cell(3) == 0) {
		print_str("Talking: It doesn't respond.");
		end();
		}
	begin_talk_mode(get_memory_cell(3));
break;