// Zapper v1.0.0
// zapper.txt
// by Kelandon (tomwatts@berkeley.edu)
//
// Much like basicnpc, but has a special ability when attacking. It zaps, which
// does damage to the target.
//
// Memory Cells:
//   Cell 0 - How creature moves.
//     0 - If 0, wander randomly. 
//     1 - Stands still until a target appears.
//     2 - Completely immobile, even if target appears.
//   Cell 1,2 - Stuff done flag. If both 0, nothing. Otherwise when this 
//     is killed, set to 1. (Example: If cell 1 is 3 and cell 2 is 5, when
//     creature is killed, sets SDF(3,5) to 1.)
//   Cell 3 - Dialogue node to start with if talked to. if left at 0, this
//     character doesn't talk.
//	 Cell 4,5 - Amount of damage to do when zapping. Will be a random amount
//		between these two numbers. If cell 5 is 0, it will default to 10.
//	 Cell 6 - Number of ticks to elapse between possible zaps. If 0, can zap
//		every turn.
//	 Cell 7 - Fraction of the probability of a zap. (So if this is 3, the
//		creature has a 1/3 chance of zapping when the turn comes around. If this
//		is not set to 1, cell 6 is probably best left at 0. If this cell is left
//		at 0, it defaults to 1.
//	 Cell 8 - If greater than 0, town script to call when dying.
//		Cell 8 was adapted at the last minute. It isn't part of the normal
//		script.

begincreaturescript;

variables;

short i,j,target,do_zap,last_abil_time;

body;

beginstate INIT_STATE;
	if (get_memory_cell(7) == 0)
		set_memory_cell(7,1);
	if (get_memory_cell(5) == 0)
		set_memory_cell(5,10);
	if (get_memory_cell(5) < get_memory_cell(4))
		{i = get_memory_cell(5);
		j = get_memory_cell(4);
		set_memory_cell(4,i);
		set_memory_cell(5,j);
		}
		
	if (get_memory_cell(0) == 2)
		set_mobility(ME,0);
	
	last_abil_time = get_current_tick();
break;

beginstate DEAD_STATE;
	// Set the appropriate stuff done flag for this character being dead
	if ((get_memory_cell(1) != 0) || (get_memory_cell(2) != 0))
		set_flag(get_memory_cell(1),get_memory_cell(2),1);
	if (get_memory_cell(8) > 0)
		run_town_script(get_memory_cell(8));
break;

beginstate START_STATE; 
	// if I have a target for some reason, go attack it
	if (target_ok()) {
		if (dist_to_char(get_target()) <= 16)
			set_state(3);
			else set_target(ME,-1);
		}
	
	// Look for a target, attack it if visible
	if (select_target(ME,8,0)) {
		do_attack();
		set_state(3);
		}
		
	// Have I been hit? Strike back!
	if (who_hit_me() >= 0) {
		set_target(ME,who_hit_me());
		do_attack();
		set_state(3);
		}
		
	// Otherwise, just peacefully move around. Go back to start, if I'm too far
	// from where I started.
	if ((my_dist_from_start() >= 6) || ((my_dist_from_start() > 0) && (get_memory_cell(0) > 0))) {
		if (get_ran(1,1,100) < 40) 
			return_to_start(ME,1);
		}
		else if (get_memory_cell(0) == 0) {
			fidget(ME,25);
			}

	// if we're in combat and the above didn't give me anything to do, just
	// stop now. Otherwise, game will keep running script, and that eats up CPU time.
	if (am_i_doing_action() == FALSE)
		end_combat_turn();
break;

beginstate 3; // attacking
	if (target_ok() == FALSE)
		if (select_target(ME,12,0) == 0)
			set_state_continue(START_STATE);
	
	// Zap.
	if (tick_difference(last_abil_time,get_current_tick()) > get_memory_cell(6))
		do_zap = get_ran(1,1,get_memory_cell(7));
	else
		do_zap = 0;
		
	if (do_zap == 1)
		{i = get_target();
		put_jagged_zap(my_loc_x(),my_loc_y(),char_loc_x(i),char_loc_y(i),5);
		put_boom_on_char(i,6,0);
		set_character_pose(my_number(),1);
		run_animation_sound(102);
		print_named_str(ME,"fires a large magic zap!");
		set_character_pose(my_number(),2);
		force_instant_terrain_redraw();
		damage_char(i,get_ran(1,get_memory_cell(4),get_memory_cell(5)),3);
		last_abil_time = get_current_tick();
		}
	
	do_attack();
break;

beginstate TALKING_STATE;
	if (get_memory_cell(3) == 0) {
		print_str("Talking: It doesn't respond.");
		end();
		}
	begin_talk_mode(get_memory_cell(3));
break;