// 2 Waypoints Through SDFs v1.0.0
// 2sdfwaypoints.txt
// by Kelandon (tomwatts@berkeley.edu)
//
// Creature moves to waypoints in response to SDFs. Creature also attacks 
// anything it hates nearby, even if it is in the process of moving between 
// waypoints. Once it has won, it returns to its home.
//
// To save memory cells, the script can call a town state when the creature dies
// (much like my Special Death script).
//
// Memory Cells:
//   Cell 0 - How creature moves.
//		0 - If 0, wander randomly. 
//		1 - Stands still until a target appears.
//		2 - Completely immobile, even if target appears.
//   Cell 1 - Which town state to call when the creature dies. If left at 0,
//		none.
//	 Cell 2 - Dialogue node to start with if talked to. if left at 0, this
//		character doesn't talk.
//	 Cell 3,4 - First SDF
//	 Cell 5,6 - Second SDF
//	 Cell 7,8 - Waypoints creature travels to if the first SDF is set. 
//		Creature goes to 7, then 8.
//	 Cell 9 - Waypoint creature travels to if the second SDF is set.
//		NOTE: Once one SDF is set, the creature stops checking for the other
//		one. So it will go to 7 and 8 OR 9, but not 7 and 8 THEN 9, for example.

begincreaturescript;

variables;

short i,target;
short moved = 0;

body;

beginstate INIT_STATE;
	set_script_mode(3);

	if (get_memory_cell(0) == 2)
		set_mobility(ME,0);
	break;

beginstate DEAD_STATE;
	// Call a town state.
	if (get_memory_cell(1) > 0)
		run_town_script(get_memory_cell(1));
break;

beginstate START_STATE; 
	// If first SDF is set, go to waypoints in mem cells 7 and 8.
	if ((get_flag(get_memory_cell(3),get_memory_cell(4)) == 1) && (moved == 0))
		set_state(4);

	// If second SDF is set, go to waypoint in mem cell 9.
	if ((get_flag(get_memory_cell(5),get_memory_cell(6)) == 1) && (moved == 0))
		set_state(5);

	// if I have a target for some reason, go attack it
	if (target_ok()) {
		if (dist_to_char(get_target()) <= 16)
			set_state(3);
			else set_target(ME,-1);
		}
	
	// Look for a target, attack it if visible
	if (select_target(ME,8,0)) {
		do_attack();
		set_state(3);
		}
		
	// Have I been hit? Strike back!
	if (who_hit_me() >= 0) {
		set_target(ME,who_hit_me());
		do_attack();
		set_state(3);
		}
		
	// Otherwise, just peacefully move around. Go back to start, if I'm too far
	// from where I started.
	if ((my_dist_from_start() >= 6) || ((my_dist_from_start() > 0) && (get_memory_cell(0) > 0))) {
		if (get_ran(1,1,100) < 40) 
			return_to_start(ME,1);
		}
		else if (get_memory_cell(0) == 0) {
			fidget(ME,25);
			}

	// if we're in combat and the above didn't give me anything to do, just
	// stop now. Otherwise, game will keep running script, and that eats up CPU time.
	if (am_i_doing_action() == FALSE)
		end_combat_turn();
break;

beginstate 3; // attacking
	if (target_ok() == FALSE)
		set_state(START_STATE);
	do_attack();
break;

beginstate 4; // moving to waypoint in mem cell 7
	// if I have a target for some reason, go attack it
	if (target_ok()) {
		if (dist_to_char(get_target()) <= 16)
			set_state(3);
			else set_target(ME,-1);
		}
	
	// Look for a target, attack it if visible
	if (select_target(ME,8,0)) {
		do_attack();
		set_state(3);
		}
		
	// Have I been hit? Strike back!
	if (who_hit_me() >= 0) {
		set_target(ME,who_hit_me());
		do_attack();
		set_state(3);
		}

	if (approach_waypoint(ME,get_memory_cell(7),1) == 1)
		{moved = 1;
		set_state(6); }
break;

beginstate 5; // moving to waypoint in mem cell 9
	// if I have a target for some reason, go attack it
	if (target_ok()) {
		if (dist_to_char(get_target()) <= 16)
			set_state(3);
			else set_target(ME,-1);
		}
	
	// Look for a target, attack it if visible
	if (select_target(ME,8,0)) {
		do_attack();
		set_state(3);
		}
		
	// Have I been hit? Strike back!
	if (who_hit_me() >= 0) {
		set_target(ME,who_hit_me());
		do_attack();
		set_state(3);
		}

	if (approach_waypoint(ME,get_memory_cell(9),1) == 1)
		{moved = 1;
		set_state(START_STATE); }
break;

beginstate 6; // moving to waypoint in mem cell 8
	// if I have a target for some reason, go attack it
	if (target_ok()) {
		if (dist_to_char(get_target()) <= 16)
			set_state(3);
			else set_target(ME,-1);
		}
	
	// Look for a target, attack it if visible
	if (select_target(ME,8,0)) {
		do_attack();
		set_state(3);
		}
		
	// Have I been hit? Strike back!
	if (who_hit_me() >= 0) {
		set_target(ME,who_hit_me());
		do_attack();
		set_state(3);
		}

	if (approach_waypoint(ME,get_memory_cell(8),1) == 1)
		set_state(START_STATE);
break;

beginstate TALKING_STATE;
	if (get_memory_cell(2) == 0) {
		print_str("Talking: It doesn't respond.");
		end();
		}
	begin_talk_mode(get_memory_cell(2));
break;