// Nolagh-Khar v1.0.0
// t15Nolagh.txt
// by Kelandon (tomwatts@berkeley.edu)
// A fairly badass villain. Reduce his power or die.
// Memory Cells:
//   Cell 0 - How creature moves.
//     0 - If 0, wander randomly. 
//     1 - Stands still until a target appears.
//     2 - Completely immobile, even if target appears.
//   Cell 1 - Which town state to call when the creature dies. If left at 0,
//		none.
//   Cell 2 - Unused.
//   Cell 3 - Dialogue node to start with if talked to. if left at 0, this
//     character doesn't talk.
//	 Cell 4 - Base ability damage. Character does twice this damage to 
//		everything near its zap if fully powered. If half-powered, character
//		does this damage to its target and then this damage again to everything
//		nearby (including the target itself).
//	 Cell 5,6 - First SDF to reduce power. This takes effect when the party
//		enters town.
//	 Cell 7,8 - Second SDF to reduce power. As above.

begincreaturescript;

variables;

short i,target;
short func_return = 0;
short power;
short last_abil_time;

body;

beginstate INIT_STATE;
	power = 3;
	if (get_flag(get_memory_cell(5),get_memory_cell(6)) == 1)
		power = power - 1;
	if (get_flag(get_memory_cell(7),get_memory_cell(8)) == 1)
		power = power - 1;
	if (get_memory_cell(0) == 2)
		set_mobility(ME,0);
break;

beginstate DEAD_STATE;
	// Call a town state.
	if (get_memory_cell(1) > 0)
		run_town_script(get_memory_cell(1));
break;

beginstate START_STATE; 
	// if I have a target for some reason, go attack it
	if (target_ok()) {
		if (dist_to_char(get_target()) <= 16)
			set_state_continue(3);
			else set_target(ME,-1);
		}
	
	// Look for a target, attack it if visible
	if (select_target(ME,8,0)) {
		set_state_continue(3);
		}
		
	// Have I been hit? Strike back!
	if (who_hit_me() >= 0) {
		set_target(ME,who_hit_me());
		set_state_continue(3);
		}
		
	// Otherwise, just peacefully move around. Go back to start, if I'm too far
	// from where I started.
	if ((my_dist_from_start() >= 6) || ((my_dist_from_start() > 0) && (get_memory_cell(0) > 0))) {
		if (get_ran(1,1,100) < 40) 
			return_to_start(ME,1);
		}
		else if (get_memory_cell(0) == 0) {
			fidget(ME,25);
			}

	// if we're in combat and the above didn't give me anything to do, just
	// stop now. Otherwise, game will keep running script, and that eats up CPU time.
	if (am_i_doing_action() == FALSE)
		end_combat_turn();
break;

beginstate 3; // attacking
if (func_return == 0)
	{if (target_ok() == FALSE)
		if (select_target(ME,8,0) == 0)
			set_state_continue(START_STATE);
	if (tick_difference(last_abil_time,get_current_tick()) > 0)
		{last_abil_time = get_current_tick();
		if (power == 3)
			set_state_continue(4);
		if (power == 2)
			set_state_continue(5);
		if (power == 1)
			set_state_continue(6);
		}
	}
	
	func_return = 0;
	end_combat_turn();
break;

beginstate 4; // Death zap ability
	i = random_party_member();
	put_jagged_zap(my_loc_x(),my_loc_y(),char_loc_x(i),char_loc_y(i),5);
	put_boom_on_char(i,6,0);
	set_character_pose(my_number(),1);
	run_animation_sound(102);
	set_character_pose(my_number(),2);
	kill_char(i,2,0);
	damage_near_loc(char_loc_x(i),char_loc_y(i),get_memory_cell(4) * 2,3,3);
	func_return = 1;
	set_state_continue(3);
break;

beginstate 5; // Hard zap ability
	i = get_target();
	put_jagged_zap(my_loc_x(),my_loc_y(),char_loc_x(i),char_loc_y(i),5);
	put_boom_on_char(i,6,0);
	set_character_pose(my_number(),1);
	run_animation_sound(102);
	set_character_pose(my_number(),2);
	force_instant_terrain_redraw();
	damage_char(i,get_memory_cell(4),3);
	damage_near_loc(char_loc_x(i),char_loc_y(i),get_memory_cell(4),3,3);
	func_return = 1;
	set_state_continue(3);
break;

beginstate 6; // No zap
	do_attack();
	func_return = 1;
	set_state_continue(3);
break;

beginstate TALKING_STATE;
	if (get_memory_cell(3) == 0) {
		print_str("Talking: It doesn't respond.");
		end();
		}
	begin_talk_mode(get_memory_cell(3));
break;