// Alternate Patroller v1.0.0
// altpatroller.txt
// by Kelandon
// Based on patrolguard.txt by Jeff Vogel
//
// A guard for a group that goes out on patrol. Walks out to a waypoint and
// then back to its start point. If it encounters an enemy, fights for one 
// round and then returns to start. If it gets back to start, alerts everyone in 
// its group.
//
// If it is not in a group (or is the only character in its group) nothing 
// special happens when it shouts its alarm.
//
// Memory Cells:
//   Cell 0 - Waypoint to which character runs when sees an enemy.
//   Cell 1,2 - Stuff done flag. If both 0, nothing. Otherwise when this 
//     is killed, set to 1. (Example: If cell 1 is 3 and cell 2 is 5, when
//     creature is killed, sets SDF(3,5) to 1.)
//   Cell 3 - Dialogue node to start with if talked to. if left at 0, this
//     character doesn't talk.
//	Cell 4,5 - Waypoints between which character walks. It just goes
//	back and forth between them until it sees an enemy.

begincreaturescript;

variables;

short i,target;

short saw_foe = 0;
short gave_alarm = 0;
short path_a_or_b = 0;
short sighting_tick = -1;

body;

beginstate INIT_STATE;
	break;

beginstate DEAD_STATE;
	// Set the appropriate stuff done flag for this character being dead
	if ((get_memory_cell(1) != 0) || (get_memory_cell(2) != 0))
		set_flag(get_memory_cell(1),get_memory_cell(2),1);
break;

beginstate START_STATE; 
	if ((saw_foe > 0) && (sighting_tick > 0)) {
		if (gave_alarm == 0) {
			if (approach_waypoint(ME,get_memory_cell(0),2) > 0) {
				gave_alarm = 1;
				print_named_str(ME,"shouts an alarm!");
				if (what_group_in(ME) >= 0)
					alert_char(1000 + what_group_in(ME));
				}
			}
		}

	// if I have a target for some reason, go attack it
	if (target_ok()) {
		if (dist_to_char(get_target()) <= 16)
			set_state(3);
			else set_target(ME,-1);
		}
	
	// Look for a target, attack it if visible
	if (select_target(ME,8,0)) {
		do_attack();
		set_state(3);
		}
		
	// Have I been hit? Strike back!
	if (who_hit_me() >= 0) {
		set_target(ME,who_hit_me());
		do_attack();
		set_state(3);
		}
		
	// Otherwise, walk to its waypoint and back.	
	if ((saw_foe == 0) && (get_memory_cell(4) >= 0) && (get_memory_cell(5) >= 0)) {
		if (path_a_or_b == 0) {
			if (get_ran(1,0,100) < 40) {
				if (approach_waypoint(ME,get_memory_cell(4),1))
					path_a_or_b = 1;	
				}	
			}
			else {
				if (get_ran(1,0,100) < 40) {
					if (approach_waypoint(ME,get_memory_cell(5),1))
						path_a_or_b = 0;	
					}
				}
		}

	// if we're in combat and the above didn't give me anything to do, just
	// stop now. Otherwise, game will keep running script, and that eats up CPU time.
	if (am_i_doing_action() == FALSE)
		end_combat_turn();
break;

beginstate 3; // attacking
	if (saw_foe == 0)
		print_named_str(ME,"has spotted you.");
	saw_foe = 1;
	
	if (sighting_tick < 0)
		sighting_tick = get_current_tick();
	if ((gave_alarm == 0) && (tick_difference(sighting_tick,get_current_tick()) >= 3)) {
		stop_moving(ME);
		set_state(START_STATE);
		}
		
	if (target_ok() == FALSE)
		set_state(START_STATE);
	do_attack();
break;

beginstate TALKING_STATE;
	if (get_memory_cell(3) == 0) {
		print_str("Talking: It doesn't respond.");
		end();
		}
	begin_talk_mode(get_memory_cell(3));
break;