// Aura v1.0.0
// aura.txt
// by Kelandon (tomwatts@berkeley.edu)
//
// Same as basicnpc, but radiates an aura of some status while in combat. Also,
// this creature optionally calls a town state when it dies, rather than just
// setting a flag.
//
// Memory Cells:
//   Cell 0 - How creature moves.
//     0 - If 0, wander randomly. 
//     1 - Stands still until a target appears.
//     2 - Completely immobile, even if target appears.
//	 Cell 1 - Which town state to call when dying. If left at 0, none.
//   Cell 2 - Dialogue node to start with if talked to. If left at 0, this
//     character doesn't talk.
//	 Cell 3 - Which status to radiate. Check Appendices for status types.
//	 Cell 4 - Amount of status to radiate.
//	 Cell 5 - Radius of radiating. Defaults to 8 if left at 0.
//	 Cell 6 - good_evil_or_all: if 0, only party-friendly creatures get the
//		status. If 1, only party-hostile creatures. If 2, all creatures.
//	 Cell 7 - Sound to play when radiating status. If left at 0, none.

begincreaturescript;

variables;

short i,j,target;

body;

beginstate INIT_STATE;
	if (get_memory_cell(0) == 2)
		set_mobility(ME,0);
	break;

beginstate DEAD_STATE;
	// Call a town state.
	if (get_memory_cell(1) > 0)
		run_town_script(get_memory_cell(1));
break;

beginstate START_STATE; 
	// if I have a target for some reason, go attack it
	if (target_ok()) {
		if (dist_to_char(get_target()) <= 16)
			set_state(3);
			else set_target(ME,-1);
		}
	
	// Look for a target, attack it if visible
	if (select_target(ME,8,0)) {
		do_attack();
		set_state(3);
		}
		
	// Have I been hit? Strike back!
	if (who_hit_me() >= 0) {
		set_target(ME,who_hit_me());
		do_attack();
		set_state(3);
		}
		
	// Otherwise, just peacefully move around. Go back to start, if I'm too far
	// from where I started.
	if ((my_dist_from_start() >= 6) || ((my_dist_from_start() > 0) && (get_memory_cell(0) > 0))) {
		if (get_ran(1,1,100) < 40) 
			return_to_start(ME,1);
		}
		else if (get_memory_cell(0) == 0) {
			fidget(ME,25);
			}

	// if we're in combat and the above didn't give me anything to do, just
	// stop now. Otherwise, game will keep running script, and that eats up CPU time.
	if (am_i_doing_action() == FALSE)
		end_combat_turn();
break;

beginstate 3; // attacking
	if (target_ok() == FALSE)
		set_state(START_STATE);
	
	if (tick_difference(i,get_current_tick()) > 0)
		{force_status_nearby(get_memory_cell(4),get_memory_cell(3),get_memory_cell(5),get_memory_cell(6));
		if (get_memory_cell(7) > 0)
			play_sound(get_memory_cell(7));
		i = get_current_tick();
		}
	
	do_attack();
break;

beginstate TALKING_STATE;
	if (get_memory_cell(2) == 0) {
		print_str("Talking: It doesn't respond.");
		end();
		}
	begin_talk_mode(get_memory_cell(2));
break;