// See And Scream v1.0.0
// seescream.txt (modification on groupnpc.txt)
// by Kelandon (tomwatts@berkeley.edu)
//
// Exactly like basicnpc, with one difference. When it first spots a foe, it 
// screams (which sends an alert message to everyone in its group) and sets a 
// flag. Good for when you have a band of monsters you don't want the party to
// be able to pick off one at a time.
//
// Memory Cells:
//   Cell 0 - How creature moves.
//     0 - If 0, wander randomly. 
//     1 - Stands still until a target appears.
//     2 - Completely immobile, even if target appears.
//   Cell 1,2 - Stuff done flag. If both 0, nothing. Otherwise when this 
//     is killed, set to 1. (Example: If cell 1 is 3 and cell 2 is 5, when
//     creature is killed, sets SDF(3,5) to 1.)
//   Cell 3 - Dialogue node to start with if talked to. if left at 0, this
//     character doesn't talk.
//   Cell 4,5 - SDF to set when creature has screamed. You MUST have an SDF
//	   specified here, or else the script will not work correctly.
//	 Cell 6 - Resource ID of sound you want it to scream. If left at 0,
//	   defaults to 111, the sound of a vahnatai dying (which is a great scream).

begincreaturescript;

variables;

short i,target;
short i_gave_alert = 0;

body;

beginstate INIT_STATE;
	if (get_memory_cell(6) == 0)
		set_memory_cell(6,111);
	if (get_memory_cell(0) == 2)
		set_mobility(ME,0);
break;

beginstate DEAD_STATE;
	// Set the appropriate stuff done flag for this character being dead
	if ((get_memory_cell(1) != 0) || (get_memory_cell(2) != 0))
		set_flag(get_memory_cell(1),get_memory_cell(2),1);
break;

beginstate START_STATE; 
	// if I have a target for some reason, go attack it
	if (target_ok()) {
		if (dist_to_char(get_target()) <= 16)
			set_state(3);
			else set_target(ME,-1);
		}
	
	// Look for a target, attack it if visible
	if (select_target(ME,8,0)) {
		do_attack();
		set_state(3);
		}
		
	// Have I been hit? Strike back!
	if (who_hit_me() >= 0) {
		set_target(ME,who_hit_me());
		do_attack();
		set_state(3);
		}
		
	// Otherwise, just peacefully move around. Go back to start, if I'm too far
	// from where I started.
	if ((my_dist_from_start() >= 6) || ((my_dist_from_start() > 0) && (get_memory_cell(0) > 0))) {
		if (get_ran(1,1,100) < 40) 
			return_to_start(ME,1);
		}
		else if (get_memory_cell(0) == 0) {
			fidget(ME,25);
			}

	// if we're in combat and the above didn't give me anything to do, just
	// stop now. Otherwise, game will keep running script, and that eats up CPU time.
	if (am_i_doing_action() == FALSE)
		end_combat_turn();
break;

beginstate 3; // attacking
	// If I can see the party, scream and set a flag, then attack it
	if (((can_see_char(1000) == 1) && (get_flag(get_memory_cell(4),get_memory_cell(5)) == 0)) &&  (what_group_in(ME) > 0))
		{print_str("You have been seen!");
		set_flag(get_memory_cell(4),get_memory_cell(5),1);
		alert_char(1000 + what_group_in(ME));
		i_gave_alert = 1;
		play_sound(get_memory_cell(6));
		}
		
	if (target_ok() == FALSE)
		set_state(START_STATE);
	do_attack();
break;

beginstate TALKING_STATE;
	if (get_memory_cell(3) == 0) {
		print_str("Talking: It doesn't respond.");
		end();
		}
	begin_talk_mode(get_memory_cell(3));
break;