// Self-Destructer v1.1
// selfdestruct.txt
// by Kelandon (tomwatts@berkeley.edu)
//
// Like basicnpc, but attacks differently. The character runs up to the party
// and explodes, destroying itself and doing some damage.
//
// Unlike v1.0, these self-destructers stay dead.
//
// Memory Cells:
//   Cell 0 - How creature moves.
//     0 - If 0, wander randomly. 
//     1 - Stands still until a target appears.
//     2 - Completely immobile, even if target appears.
//   Cell 1,2 - Stuff done flag. If both 0, nothing. Otherwise when this 
//     is killed, set to 1. (Example: If cell 1 is 3 and cell 2 is 5, when
//     creature is killed, sets SDF(3,5) to 1.)
//   Cell 3 - Dialogue node to start with if talked to. if left at 0, this
//     character doesn't talk.
//	 Cell 4 - Damage to do when exploding. If left at 0, defaults to three times
//		the creature's level.
//	 Cell 5 - Radius of damage. If left at 0, defaults to 2.
//	 Cell 6 - Type of damage to do.
//		0 - weapon
//		1 - fire
//		2 - poison
//		3 - general magic
//		4 - unblockable
//		5 - cold
//		6  acid
//	 Cell 7 - Kind of explosion when exploding. Check the appendices on
//		put_boom_on_char for details.

begincreaturescript;

variables;

short i,target;

body;

beginstate INIT_STATE;
	if ((get_memory_cell(1) != 0) || (get_memory_cell(2) != 0))
		if (get_flag(get_memory_cell(1),get_memory_cell(2)) == 1)
			erase_char(ME);
			
	if (get_memory_cell(4) == 0)
		set_memory_cell(4,get_level(my_number()) * 3);
		
	if (get_memory_cell(5) == 0)
		set_memory_cell(5,2);
	
	if (get_memory_cell(0) == 2)
		set_mobility(ME,0);
break;

beginstate DEAD_STATE;
	print_named_str(ME,"explodes!");
	put_boom_on_char(my_number(),get_memory_cell(7),0);
	run_animation_sound(152);
	damage_nearby(get_memory_cell(4),get_memory_cell(5),get_memory_cell(6),2);
	// Set the appropriate stuff done flag for this character being dead
	if ((get_memory_cell(1) != 0) || (get_memory_cell(2) != 0))
		set_flag(get_memory_cell(1),get_memory_cell(2),1);
break;

beginstate START_STATE; 
	// if I have a target for some reason, go attack it
	if (target_ok()) {
		if (dist_to_char(get_target()) <= 16)
			set_state(3);
			else set_target(ME,-1);
		}
	
	// Look for a target, attack it if visible
	if (select_target(ME,8,0)) {
		do_attack();
		set_state(3);
		}
		
	// Have I been hit? Strike back!
	if (who_hit_me() >= 0) {
		set_target(ME,who_hit_me());
		do_attack();
		set_state(3);
		}
		
	// Otherwise, just peacefully move around. Go back to start, if I'm too far
	// from where I started.
	if ((my_dist_from_start() >= 6) || ((my_dist_from_start() > 0) && (get_memory_cell(0) > 0))) {
		if (get_ran(1,1,100) < 40) 
			return_to_start(ME,1);
		}
		else if (get_memory_cell(0) == 0) {
			fidget(ME,25);
			}

	// if we're in combat and the above didn't give me anything to do, just
	// stop now. Otherwise, game will keep running script, and that eats up CPU time.
	if (am_i_doing_action() == FALSE)
		end_combat_turn();
break;

beginstate 3; // attacking
	// If char can't find a target, go back to targeting in START_STATE.
	if (target_ok() == FALSE)
		set_state(START_STATE);
		
	// Try to walk to the target.
	i = approach_char(ME,get_target(),1);
	
	// If char is close enough, self-destruct.
	if (i)
		{if (dist_to_party() <= get_memory_cell(5))
			kill_char(my_number(),2,0);
		
		// If char isn't close enough, but for some reason can't get there, just
		// attack normally.
		else
			do_attack();
		}
break;

beginstate TALKING_STATE;
	if (get_memory_cell(3) == 0) {
		print_str("Talking: It doesn't respond.");
		end();
		}
	begin_talk_mode(get_memory_cell(3));
break;