// Standing Guard v1.0.0
// standingguard.txt
// by Kelandon (tomwatts@berkeley.edu)
// Based on patrolguard.txt by Jeff Vogel
//
// A guard for a group that stands. If it encounters an enemy, it runs to a waypoint. 
// If it gets to the waypoint, alerts everyone in its group.
// If it is not in a group (or is the only character in its group) nothing 
// special happens when it shouts its alarm.
//
// Memory Cells:
//   Cell 0 - How creature moves.
//     0 - If 0, wander randomly. 
//     1 - Stands still until a target appears.
//     2 - Completely immobile, even if target appears.
//   Cell 1,2 - Stuff done flag. If both 0, nothing. Otherwise when this 
//     is killed, set to 1. (Example: If cell 1 is 3 and cell 2 is 5, when
//     creature is killed, sets SDF(3,5) to 1.)
//   Cell 3 - Dialogue node to start with if talked to. if left at 0, this
//     character doesn't talk.
//	Cell 4 - Waypoint towards which to run when creature sees an enemy.

begincreaturescript;

variables;

short i,target;

short saw_foe = 0;
short gave_alarm = 0;
short path_a_or_b = 0;
short sighting_tick = -1;

body;

beginstate INIT_STATE;
	break;

beginstate DEAD_STATE;
	// Set the appropriate stuff done flag for this character being dead
	if ((get_memory_cell(1) != 0) || (get_memory_cell(2) != 0))
		set_flag(get_memory_cell(1),get_memory_cell(2),1);
break;

beginstate START_STATE; 
	if ((saw_foe > 0) && (sighting_tick > 0)) {
		if (gave_alarm == 0) {
			if (approach_waypoint(ME,get_memory_cell(4),1)) {
				gave_alarm = 1;
				print_named_str(ME,"shouts an alarm!");
				if (what_group_in(ME) >= 0)
					alert_char(1000 + what_group_in(ME));
				}
			}
		}

	// if I have a target for some reason, go attack it
	if (target_ok()) {
		if (dist_to_char(get_target()) <= 16)
			set_state(3);
			else set_target(ME,-1);
		}
	
	// Look for a target, attack it if visible
	if (select_target(ME,8,0)) {
		do_attack();
		set_state(3);
		}
		
	// Have I been hit? Strike back!
	if (who_hit_me() >= 0) {
		set_target(ME,who_hit_me());
		do_attack();
		set_state(3);
		}
		
	// Otherwise, just peacefully move around. Go back to start, if I'm too far
	// from where I started.
	if ((my_dist_from_start() >= 6) || ((my_dist_from_start() > 0) && (get_memory_cell(0) > 0))) {
		if (get_ran(1,1,100) < 40) 
			return_to_start(ME,1);
		}
		else if (get_memory_cell(0) == 0) {
			fidget(ME,25);
			}

	// if we're in combat and the above didn't give me anything to do, just
	// stop now. Otherwise, game will keep running script, and that eats up CPU time.
	if (am_i_doing_action() == FALSE)
		end_combat_turn();
break;

beginstate 3; // attacking
	if (saw_foe == 0)
		{print_named_str(ME,"has spotted you.");
		saw_foe = 1; 
		set_state(START_STATE); }

	set_state(START_STATE);
break;

beginstate TALKING_STATE;
	if (get_memory_cell(3) == 0) {
		print_str("Talking: It doesn't respond.");
		end();
		}
	begin_talk_mode(get_memory_cell(3));
break;